79 lines
4.4 KiB
Plaintext
79 lines
4.4 KiB
Plaintext
импорт Основное
|
||
импорт Пресейл
|
||
|
||
@Обработчик
|
||
метод ПослеЧтения()
|
||
если ЭтоНовый()
|
||
Объект.Владелец = Сделка
|
||
;
|
||
;
|
||
|
||
@Обработчик
|
||
метод ПередЗаписьюОбъекта()
|
||
пер ПоляНеЗаполнены: Булево
|
||
если Объект.Наименование.Сократить().Пусто()
|
||
Компоненты.ПолеВводаНаименование.РезультатПроверкиДанных = РезультатПроверкиДанных.Ошибка
|
||
ПоляНеЗаполнены = Истина
|
||
иначе
|
||
Компоненты.ПолеВводаНаименование.РезультатПроверкиДанных = РезультатПроверкиДанных.Отсутствует
|
||
;
|
||
если Объект.Владелец == Неопределено
|
||
Компоненты.ПолеВводаСделка.РезультатПроверкиДанных = РезультатПроверкиДанных.Ошибка
|
||
ПоляНеЗаполнены = Истина
|
||
иначе
|
||
Компоненты.ПолеВводаСделка.РезультатПроверкиДанных = РезультатПроверкиДанных.Отсутствует
|
||
;
|
||
если ПоляНеЗаполнены
|
||
выбросить новый ИсключениеВалидации("Не заполнены обязательные поля", ОтображатьСообщениеОбОшибке = Ложь)
|
||
;
|
||
|
||
если ЭтоНовый()
|
||
Объект.ДатаСоздания = Момент.Сейчас()
|
||
иначе
|
||
ПоказыватьУведомление = Ложь
|
||
;
|
||
;
|
||
|
||
@Обработчик
|
||
метод ПослеЗаписиОбъекта()
|
||
ЗаписаноСобытие.Оповестить()
|
||
|
||
если ПоказыватьУведомление
|
||
знч Уведомление = новый Уведомление(ЛокализованныеСтроки.СозданиеСобытия(), ЛокализованныеСтроки.СозданоСобытие(Объект.Наименование))
|
||
Уведомление.Данные = КлючОбъекта
|
||
Уведомление.ОценкаИнформации = ОценкаИнформации.Положительная
|
||
Уведомление.Показать()
|
||
;
|
||
;
|
||
|
||
@Обработчик
|
||
метод ПослеУдаленияОбъекта(ПараметрыУдаления: Объект)
|
||
ЗаписаноСобытие.Оповестить()
|
||
;
|
||
|
||
метод ДобавитьУчастникаПриНажатии(Источник: Кнопка, Событие: СобытиеПриНажатии)
|
||
знч Клиент = Объект.Владелец != Неопределено ? ПолучитьКлиентаСделки(Объект.Владелец) : Неопределено
|
||
знч ДанныеУчастника = ФормаДобавленияУчастника.ОткрытьВМодальномОкне(Клиент = Клиент)
|
||
если ДанныеУчастника это УчастникиМероприятия
|
||
ДобавитьУчастника(ДанныеУчастника)
|
||
;
|
||
;
|
||
|
||
метод УдалитьУчастникаПриНажатии(Команда: КомандаСПараметром<Массив<УчастникиМероприятия>>, Параметр: Массив<УчастникиМероприятия>)
|
||
УдалитьУчастника(Параметр.Единственный())
|
||
;
|
||
|
||
метод ДобавитьУчастника(Участник: УчастникиМероприятия)
|
||
если не Объект.Участники.Содержит(Участник)
|
||
Объект.Участники.Добавить(Участник)
|
||
;
|
||
;
|
||
|
||
метод УдалитьУчастника(Участник: УчастникиМероприятия)
|
||
Объект.Участники.Удалить(Участник)
|
||
;
|
||
|
||
@НаСервере @ДоступноСКлиента
|
||
статический метод ПолучитьКлиентаСделки(Сделка: Сделки.Ссылка): Клиенты.Ссылка?
|
||
возврат Сделки.ПолучитьКлиентаСделки(Сделка)
|
||
; |